Lab 3 Overview

/******************************************************************************
ME 571 Tutorial 3 - Part 0
Reading values off of your Force Sensitive Resistor 
Using a Force Sensitive Resistor (FSR) to trigger the mini-pump on/off.

This tutorial relies on creating a voltage divider circuit with the FSR 
and reading the analog voltage at pin A0. A conversion equation will
return the force in grams. 

Create a voltage divider circuit combining an FSR with a 3kOhm resistor.
- The resistor should connect from A0 to GND.
- The FSR should connect from A0 to R_DIV
As the resistance of the FSR decreases (meaning an increase in pressure), the
voltage at A0 should increase.

Use the serial monitor to see the values reorted from the sensor.Alternatively,
use the serial plotter to see a graphical representation of the vlaues.

To use serial plotter, go to "Tools -> Serial Plotter".
******************************************************************************/
const int FSR_PIN = A0; // Pin connected to FSR/resistor divider
const float VCC = 5.0; 
const float R_DIV = 3000.0; 

void setup() 
{
  Serial.begin(115200);
  pinMode(FSR_PIN, INPUT);
}

void loop(){
  float forceVal;
  forceVal = readForce();
  
  Serial.println("Force: " + String(forceVal) + " g");
  Serial.println();
  delay(500);
}


float readForce() 
{
  int fsrADC = analogRead(FSR_PIN);
  // If the FSR has no pressure, the resistance will be
  // near infinite. So the voltage should be near 0.
  if (fsrADC != 0) // If the analog reading is non-zero
  {
    // Use ADC reading to calculate voltage:
    float fsrV = fsrADC * VCC / 1023.0;
    // Use voltage and static resistor value to 
    // calculate FSR resistance:
    float fsrR = R_DIV * (VCC / fsrV - 1.0);
    // Linearized estimate of force based on slopes in figure 3 of
    // FSR datasheet:
    float force;
    float fsrG = 1.0 / fsrR; // Calculate conductance
    // Break parabolic curve down into two linear slopes:
    if (fsrR <= 600){
        force = (fsrG - 0.00075) / 0.00000032639;
      	return force;
    }else{
        force =  fsrG / 0.000000642857;
        return force;
    }
  }
}

/******************************************************************************
ME 571 Tutorial 3 - Part 1
Using a Force Sensitive Resistor (FSR) to trigger the mini-pump on/off.

This tutorial relies on creating a voltage divider circuit with the FSR 
and reading the analog voltage at pin A0. A conversion equation will
return the force in grams. 

Create a voltage divider circuit combining an FSR with a 3kOhm resistor.
- The resistor should connect from A0 to GND.
- The FSR should connect from A0 to R_DIV
As the resistance of the FSR decreases (meaning an increase in pressure), the
voltage at A0 should increase.

******************************************************************************/
#include <Wire.h>
#include <Adafruit_MPRLS.h>

#define RESET_PIN  -1  // set to any GPIO pin # to hard-reset on begin()
#define EOC_PIN    -1  // set to any GPIO pin to read end-of-conversion by pin
Adafruit_MPRLS mpr = Adafruit_MPRLS(RESET_PIN, EOC_PIN);
/**************************/
int pumpPin = 2;
int solenoidInlet = 3;
int solenoidExhaust = 4;
/**************************/
const int FSR_PIN = A0; // Pin connected to FSR/resistor divider
const float VCC = 5.0; 
const float R_DIV = 3000.0; 
/******************************************************************************/

void setup() {

  //Begin Serial Monitor ******************************************************
  Serial.begin(115200);

  //Establish communication with MPRLS Pressure Sensor ************************
  if (! mpr.begin()) {
    Serial.println("Failed to communicate with MPRLS sensor, check wiring?");
    while (1) {
      delay(10);
    }
  }
  Serial.println("Found MPRLS sensor");
  
  //declare pin I/O ************************************************************
  pinMode(pumpPin, OUTPUT);
  pinMode(solenoidInlet,OUTPUT);
  pinMode(solenoidExhaust,OUTPUT);
  
  //Initial deflate routine that will run once. Will depressurize any air that's
  //already in the line. 
  digitalWrite(solenoidInlet, HIGH);   //open inlet valve 
  digitalWrite(solenoidExhaust, HIGH); //open exhaust valve
  delay(5000);                         //wait 5 seconds for system to deflate

}

void loop() {
  float forceVal = readForce();
  float pressure_hPa = mpr.readPressure();

  if (forceVal > 600) {
    digitalWrite(solenoidInlet, HIGH);
    digitalWrite(solenoidExhaust, LOW);
    digitalWrite(pumpPin, HIGH);
  }
  else {
   digitalWrite(solenoidInlet, HIGH);
   digitalWrite(solenoidExhaust, HIGH);
   digitalWrite(pumpPin, LOW); 
  }
  Serial.print("Pressure (PSI): "); Serial.println(pressure_hPa / 68.947572932);
}


//Functions
/**********************************************************************************/
float readForce() 
{
  int fsrADC = analogRead(FSR_PIN);
  // If the FSR has no pressure, the resistance will be
  // near infinite. So the voltage should be near 0.
  if (fsrADC != 0) // If the analog reading is non-zero
  {
    // Use ADC reading to calculate voltage:
    float fsrV = fsrADC * VCC / 1023.0;
    // Use voltage and static resistor value to 
    // calculate FSR resistance:
    float fsrR = R_DIV * (VCC / fsrV - 1.0);
    // Linearized estimate of force based on slopes in figure 3 of
    // FSR datasheet:
    float force;
    float fsrG = 1.0 / fsrR; // Calculate conductance
    // Break parabolic curve down into two linear slopes:
    if (fsrR <= 600){
        force = (fsrG - 0.00075) / 0.00000032639;
        return force;
    }else{
        force =  fsrG / 0.000000642857;return force;}
  }
  else
  {
    // No pressure detected
  }
}